AutoHotKey是一个Windows上的脚本语言,比CMD提供更加方便的系统调用,而且有很好的社区创意,以下内容就是来自社区贡献的代码。

保存以下内容为SwitchProxy.ahk,双击运行,按ScrollLock键切换是否使用代理,代理地址同IE设置。

; File encoding:  GB2312
#SingleInstance force
Menu, Tray, Click, 1
Menu, Tray, NoStandard
Menu, Tray, Add, 切换代理, SwitchProxy
Menu, Tray, Add, 退出, Exit
Menu, Tray, Default, 切换代理

; 读取代理地址到ProxyServer
InputBox, ProxyServer, 代理地址, 请输入代理地址,,300, 150,,,,,127.0.0.1:8080
ProxyEnable:=0
if ErrorLevel
  ExitApp

SwitchProxy:
ProxyEnable:=!ProxyEnable
RegWrite,REG_SZ,HKCU,Software\Microsoft\Windows\CurrentVersion\Internet Settings,ProxyServer, % ProxyEnable?ProxyServer:
RegWrite,REG_DWORD,HKCU,Software\Microsoft\Windows\CurrentVersion\Internet Settings,ProxyEnable, %ProxyEnable%
; 更新代理设置
DllCall("wininet\InternetSetOptionW",int,0,int,39,int,0,int,0)
DllCall("wininet\InternetSetOptionW",int,0,int,37,int,0,int,0)
; 发送提示信息
ProxyState:=ProxyEnable?"ON":"OFF"
Menu, Tray, Icon, pnidui.dll, % ProxyEnable?41:42
Menu,Tray,Tip,系统代理 %ProxyState%
TrayTip % Format("系统代理 {:U}",ProxyState),代理地址: %ProxyServer%
return

; ScrollLock切换代理状态
ScrollLock::
gosub,SwitchProxy
return

Exit:
ProxyEnable:=1
gosub,SwitchProxy
ExitApp
return

参考来源:
AHK FORMS: Switch Proxy On or Off

原文链接:https://marskid.net/2019/02/22/switchproxy-ahk/